Question

How to get the indexes of words from an array of strings that start with a specific letter in VB.NET

Answer 1

Imports System
Imports System.Collections.Generic
Imports System.Runtime.CompilerServices

Module Extensions
    <Extension()>
    Iterator Function IndexesWhere(Of T)(ByVal source As IEnumerable(Of T), ByVal predicate As Func(Of T, Boolean)) As IEnumerable(Of Integer)
        Dim index As Integer = 0

        For Each element As T In source
            If predicate(element) Then
                Yield index
            End If

            index += 1
        Next
    End Function
End Module

Public Class Program
    Public Shared Sub Main()
	    Dim s As String() = {"zero", "one", "two", "three", "four", "five", "six", "seven", "eight", "nine", "ten", "let’s start again"}
        
		Dim indexes = s.IndexesWhere(Function(t) t.StartsWith("t"))
        
		Console.Write(String.Join(", ", indexes))
    End Sub
End Class



' run:
'
' 2, 3, 10
'

 

70+ SQL courses for beginners and professionals

Answer 2

Imports System
Imports System.Collections.Generic

Public Class Program
    Public Shared Function getIndexes(ByVal s As String()) As List(Of Integer)
        Dim indexes As List(Of Integer) = New List(Of Integer)()

        For i As Integer = 0 To s.Length - 1
            If s(i)(0) = "t"c Then
                indexes.Add(i)
            End If
        Next

        Return indexes
    End Function

    Public Shared Sub Main()
        Dim s As String() = {"zero", "one", "two", "three", "four", "five", "six", "seven", "eight", "nine", "ten", "let’s start again"}
	
        Dim indexes As List(Of Integer) = getIndexes(s)
        
	Console.Write(String.Join(", ", indexes))
    End Sub
End Class



' run:
'
' 2, 3, 10
'

 

70+ SQL courses for beginners and professionals